CODE

import fl.transitions.*;
import fl.transitions.easing.*;

//AplicamCLICK listat pentru fiecare text din meniu
page01Button.addEventListener (MouseEvent.CLICK, buttonclicked);
page02Button.addEventListener (MouseEvent.CLICK, buttonclicked);
page03Button.addEventListener (MouseEvent.CLICK, buttonclicked);

//facem astfel incat fiecare buton sa arate ca buton (la apropierea sagetii sa se transforme in cursor cu degetel)
page01Button.buttonMode = true;
page02Button.buttonMode = true;
page03Button.buttonMode = true;

//acest loader se foloseste pentru incarcarea fisierelor externe swf
var loader:Loader;

//URLRequest patreaza calea catre fisier incarcat
var urlRequest:URLRequest;

//acest masiv salveaza tweens, sa nu fie aruncate la gunoi

var tweens:Array = new Array();

//Memoreaza pagina curenta luminata
var currentPage:MovieClip = null;

//Memoram pagina urmatoare, pe care dorim sa o luminam/aratam
var nextPage:MovieClip = null;

//La aceasta functie se apeleaza atunci cand dam click
function buttonclicked (e:Event):void {

//Creaza loader nou
loader = new Loader();

//Daca click pe buton din dreapta atunci se incarca page1
if (e.target == page01Button) {

urlRequest = new URLRequest("page1.swf");
loader.load (urlRequest);
}

//Daca click pe buton 2 atunci se incarca  page2
else if (e.target == page02Button) {
urlRequest = new URLRequest("page2.swf");
loader.load (urlRequest);
}

//Incarcam page3, deoarece se stie ca  page01Button sau page02Button
//n-au fost apasate
else {

urlRequest = new URLRequest("page3.swf");
loader.load (urlRequest);
}

//Dorim sa stim cand se finalizeaza incarcarea urmatoarei pagini
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, fileLoaded);

}

//Aceasta functie se apeleaza cand s-a finalizat incarcarea paginii content
function fileLoaded(e:Event):void {

//Загрузчик содержит страницу, которую мы собираемся высветить.
nextPage = e.target.content;

//Sa animam pagina curenta din scenariu.
//in primul rand trebuie sa fim siguri ca pagina curenta e pe scena.
if(currentPage != null) {

//tween paginii curente de la stanga spre dreapta
var tweenX:Tween = new Tween(currentPage, "x", Regular.easeOut,
     currentPage.x, 500, 1, true);

//Micsoram alfa pana la 0
var tweenAlpha:Tween = new Tween(currentPage, "alpha", Regular.easeOut,
     1, 0, 1, true);

//Inseram tweenurile in masiv
tweens.push(tweenX);
tweens.push(tweenAlpha);

//currentPageGone va fi apelata cand tween se finalizeaza
tweenX.addEventListener(TweenEvent.MOTION_FINISH, currentPageGone);
}

//Pagina curenta nui, deci putem sa animam pagina urmatoare din scenariu
// Animatia se petrece in functia showNextPage
else {
showNextPage();
}
}

//Aceasta functie animeaza si arata urmatoarea pagina
function showNextPage():void {

//Tween paginii urmatoare  de la stanga spre centru
var tweenX:Tween = new Tween(nextPage, "x", Regular.easeOut,
     -200, 0, 1, true);

//Tween alfa de la 0 la 1
var tweenAlpha:Tween = new Tween(nextPage, "alpha", Regular.easeOut,
     0, 1, 1, true);

//Inseram tweenurile in masiv
tweens.push(tweenX);
tweens.push(tweenAlpha);

//Adaugam urmatoare pagina in scenaruiu
addChild(nextPage);

//urmatoare pagina- acum pagina curenta
currentPage = nextPage;
}

//Aceasta functie se apeleaza atunci cand se animeaza pagina curenta
function currentPageGone(e:Event):void {

//Stergem pagina curenta
removeChild(currentPage);

//Sa aratam urmatoarea pagina
showNextPage();
}